Yes, absolutely. Thanks for clarifying the question. I have filed a bug #616658 to improve the upgrade script.
As a workaround, you can remove the section of setting routing_xml to null from mssql_upg110_120.sql and do it separately in the way you mentioned. There won't be any problem excluding rows where the routing_xml column is already NULL or applying batched updates.

This is the script that I have put together. Do you see any problems with it?

IF EXISTS (
    SELECT *
    FROM [dbo].[cf_options]
    WHERE optionname = 'UpgradeStep'
      AND optionvalue IS NOT NULL
      AND ISNUMERIC(optionvalue) = 1
      AND CAST(optionvalue AS INT) = 1215
)
BEGIN
    DECLARE @BatchSize INT = 1000;
    DECLARE @RowCount INT;

    -- Update main_instance_extended_data in batches
    SET @RowCount = 1;
    WHILE @RowCount > 0
    BEGIN
        BEGIN TRANSACTION;

        WITH CTE AS (
            SELECT TOP (@BatchSize) *
            FROM [dbo].[main_instance_extended_data]
            WHERE routing_xml IS NOT NULL
        )
        UPDATE CTE
        SET routing_xml = NULL;

        SET @RowCount = @@ROWCOUNT;

        COMMIT;
    END

    -- Update worker_instance_history_extended_data in batches
    SET @RowCount = 1;
    WHILE @RowCount > 0
    BEGIN
        BEGIN TRANSACTION;

        WITH CTE AS (
            SELECT TOP (@BatchSize) *
            FROM [dbo].[worker_instance_history_extended_data]
            WHERE routing_xml IS NOT NULL
        )
        UPDATE CTE
        SET routing_xml = NULL;

        SET @RowCount = @@ROWCOUNT;

        COMMIT;
    END

    -- Update UpgradeStep
    IF EXISTS (
        SELECT *
        FROM [dbo].[cf_options]
        WHERE optionname = N'UpgradeStep'
    )
    BEGIN
        UPDATE [dbo].[cf_options]
        SET optionvalue = N'1216'
        WHERE optionname = N'UpgradeStep';
    END
    ELSE
    BEGIN
        INSERT INTO [dbo].[cf_options] ([optionname], [optionvalue])
        VALUES (N'UpgradeStep', N'1216');
    END
END
GO