Kay,

This is more of an academic challenge because there are several variables that make it difficult to calculate an actual keystroke count. 

First, it is not quite as easy as counting the length of the metadata values stored in the fields.  Some metadata field types (i.e. List) can be successfully entered with only a single keystroke.  In other words you can potentially select the list value of 'Abracadabra' by keying in only an 'A'.  The same with Dates and Times; you can key in either 6 or 8 numbers for a Date, and 4 or 6 numbers for a Time (depending on the format mask and workstation settings).

In addition, if you are using only the keyboard to enter data you have to hit the TAB key twice to get to the next metadata field in a template.

All of that being said; here is a code snippet for an SDK Script activity that will do some keystroke 'calculations' for a particular document with metadata assigned.  The assumptions are in the Select Case branching logic where text and numeric fields keystroke counts will be the length of the data.  List fields only get 1 keystroke, dates and time more keystrokes.  (Note: You can edit the script to set those values to any numbers you please).

In the end you are much better off going to some type of import tool like EzeScan (posted earlier)

        Protected Overrides Sub Execute()
            Dim keystrokeCount As Integer = 0
            Dim fieldCount As Integer = 0

            Try

                'Only look at documents...
                If Me.BoundEntryInfo.EntryType = EntryType.Document Then

                    For Each kvp As KeyValuePair(Of String, Object) In Me.BoundEntryInfo.GetFieldValues

                        'Only look at fields that have a value...
                        If kvp.Value IsNot Nothing Then
                            Dim fi As FieldInfo = Field.GetInfo(kvp.Key, Me.RASession)

                            fieldCount += 1

                            Select Case fi.FieldType

                                'Assume that each character in a text field was keyed...
                                Case FieldType.String
                                    keystrokeCount += kvp.Value.ToString.Length

                                'Assume that each character in a number field was keyed...
                                Case FieldType.Number
                                    keystrokeCount += kvp.Value.ToString.Length

                                'Assume that each character in an integer field was keyed...
                                Case FieldType.ShortInteger
                                    keystrokeCount += kvp.Value.ToString.Length

                                'Assume that each character in a long integer field was keyed...
                                Case FieldType.LongInteger
                                    keystrokeCount += kvp.Value.ToString.Length

                                'Make an assumption that the user keyed in 8 numbers for a date...
                                'Literals do not count ('/' or '-')
                                Case FieldType.Date
                                    keystrokeCount += 8

                                'Make an assumption that the user keyed in 4 numbers for a time...
                                'Literals do not count (':')
                                Case FieldType.Time
                                    keystrokeCount += 4

                                'Make an assumption that the user keyed in 12 numbers for a datetime...
                                'Literals do not count ('/', '-', ':')
                                Case FieldType.DateTime
                                    keystrokeCount += 12

                                'List valuess can be selected by keying in just 1 value...
                                Case FieldType.List
                                    keystrokeCount +=1

                            End Select

                        End If

                    Next
            End If

            Catch ex As Exception
                Me.WorkflowApi.TrackError(ex.message)

            End Try

            Me.SetTokenValue("Keystrokes", keystrokeCount)
            Me.SetTokenValue("FieldCount", fieldCount)

        End Sub

Usage in a workflow might be something like this where you do a repository search and then iterate through the resulting documents and add up the 'keystrokes'.