Thanks Robbie! That worked perfectly.

In case anyone is interested, here is the code I ended up using (in VB.NET; the formatting doesn't look great below):

'Create global variables.
Dim skipFinalErrorMessage As Boolean = False

Using lfclient As New ClientManager()

'Get all Laserfiche Client instances that are open on the machine.
Dim clients As IEnumerable(Of ClientInstance) = lfclient.GetAllClientInstances()

'Iterate over each open Laserfiche Client.
For Each client As ClientInstance In clients
	
'Only proceed if the Laserfiche Client is logged in.
	If client.IsLoggedIn = True Then
		
'Get the Laserfiche Client's open windows.
		Dim windows As IEnumerable(Of ClientWindow) = client.GetAllClientWindows()
		
'Iterate over each window.
		For Each window As ClientWindow In windows
			
'Retrieve the Laserfiche Client's connection.
			Dim repoConnection As RepositoryConnection = window.GetCurrentRepository
			
'Only proceed if a connection was successfully retrieved.
			If Not repoConnection Is Nothing Then
				
'Clone the retrieved connection.
				Dim currentSession As Session = Session.CreateFromSerializedLFConnection(repoConnection.GetSerializedConnection)
				
				If window.GetWindowType = ClientWindowType.Main Then
					
'Get the "main" window.
					Dim mainWindow As MainWindow = TryCast(window, MainWindow)
					
					Try
					
'Get the active entry's path.
					Dim currentEntryInfo As EntryInfo = Entry.GetEntryInfo(mainWindow.GetCurrentFolderId, currentSession)
					
'Attempt to find an order number within the active entry's path using regex.
					Dim regex As Regex = New Regex("\\Operations\\Active Orders\\Order (\d+) - .+")
					Dim match As Match = regex.Match(currentEntryInfo.Path)
					
'If an order number can be found, use it get the appropriate order folder and open its metadata.
'Otherwise throw an error.
					If match.Success Then
						
'Minimize this program.
						Me.WindowState = FormWindowState.Minimized
						
'Open the order folder's metadata.
						Dim options As New OpenOptions()
						options.OpenStyle = DocumentOpenType.Metadata
						mainWindow.OpenDocumentById(match.Groups.Item(1).Value, options)
						
						skipFinalErrorMessage = True
						
					Else
						
						MessageBox.Show("Could not find an order folder." & Environment.NewLine & Environment.NewLine & "Ensure that you are currently inside of a green order folder, then try again.", "View Order Metadata", MessageBoxButtons.OK, MessageBoxIcon.Warning)
						
						skipFinalErrorMessage = True
						
					End If
					
					Catch ex As Exception
					
					MessageBox.Show("Uh oh! Something went wrong." & Environment.NewLine & Environment.NewLine & "Contact your Laserfiche administrator for help.", "View Order Metadata", MessageBoxButtons.OK, MessageBoxIcon.Warning)
					
					skipFinalErrorMessage = True
					
					End Try
					
				ElseIf window.GetWindowType = ClientWindowType.DocumentViewer Then
					
'The Client Window is not of the "main" type.
'Do nothing and move on.
					
				End If
				
			End If
			
		Next
		
'If no valid windows were processed, inform the user.
		If skipFinalErrorMessage = False Then
			
			MessageBox.Show("The Laserfiche Client must be open, logged in, and in a valid state.", "Laserfiche Form Launcher", MessageBoxButtons.OK, MessageBoxIcon.Warning)
			
		End If
		
	End If
	
'Dispose of the Laserfiche Client instance, to avoid leaked instances of LF.exe.
	client.Dispose()
	
Next

Note: I ended up not using the template name to determine where the master order folder was. I found it less expensive (and easier) to regex the path instead.